Type property (Element)

Возвращает/устанавливает тип типового объекта.

Применяется к:

Element

Синтаксис:

Visual Basic:

Property Type As ObjectType

Описание:

При чтении возвращается тип объекта из структуры слоя (ObjectType); у примитива - Nothing.

Новый тип задается его ID (ObjectType.Id) или названием (ObjectType.Name); объект получает режим 1 нового типа, изменение сразу вносится в слой. Если тип другого графического вида (например, линейный тип для символа), присваивание без ошибки ничего не меняет. Сменить тип и режим одним вызовом позволяет метод ChangeTypeMode.

В случае неудачи возникает исключение с одним из следующих кодов:

Код

Описание

517

Неправильный тип слоя: объект растрового слоя (и при чтении, и при записи).

521

Типа с таким ID или названием в структуре слоя нет. Тот же код возникает в Visual Basic при попытке присвоить сам объект ObjectType; с Set - ошибка 438.

522

Объект - примитив.

В Python исключений 521 и 522 нет: присваивание несуществующего типа и присваивание примитиву проходят без ошибки, а сам объект ObjectType не принимается (TypeError).

Пример:

Пример ставит за краем данных активного слоя символ первого символьного типа и переводит его во второй символьный тип.

Visual Basic:

Sub Element_Type
'Берем активный слой карты и его габариты
Set L = Zulu.ActiveMapDoc.Layers.Active
Set R = L.GetBoundsRectangle
'Собираем ID первых двух символьных типов
Set OTs = L.ObjectTypes
T1 = -1
T2 = -1
For i = 0 To OTs.Count - 1
  Set OT = OTs.GetItemByIndex(i)
  'GraphicType = 1 - символьный тип
  If OT.GraphicType = 1 Then
    If T1 = -1 Then
      T1 = OT.Id
    ElseIf T2 = -1 Then
      T2 = OT.Id
    End If
  End If
Next
If T2 = -1 Then
  MsgBox "В слое меньше двух символьных типов"
Else
  'Ставим символ первого типа за краем данных слоя
  Key = L.AddSymbol(R.Xmax + (R.Xmax - R.Xmin) / 10, R.Ymin, T1, 1)
  Msg = "Символ " & Key & ": тип '" & L.Elements.Item(Key).Type.Name & "'"
  'Переводим его во второй тип по ID
  L.Elements.Item(Key).Type = T2
  MsgBox Msg & " -> '" & L.Elements.Item(Key).Type.Name & "'"
End If
End Sub

Python:

import zulu

def Macro_Element_Type():
    # Берем активный слой карты и его габариты
    L = zulu.App.ActiveMapDoc.Layers.Active
    R = L.GetBoundsRectangle()
    # Собираем ID символьных типов (GraphicType = 1)
    OTs = L.ObjectTypes
    ids = [OTs.GetItemByIndex(i).Id for i in range(OTs.Count) if OTs.GetItemByIndex(i).GraphicType == 1]
    if len(ids) < 2:
        print("В слое меньше двух символьных типов")
        return
    # Ставим символ первого типа за краем данных слоя
    key = L.AddSymbol(R.Xmax + (R.Xmax - R.Xmin) / 10, R.Ymin, ids[0], 1)
    name1 = L.Elements.Item(key).Type.Name
    # Переводим его во второй тип по ID
    L.Elements.Item(key).Type = ids[1]
    print("Символ", key, ": тип", repr(name1), "->", repr(L.Elements.Item(key).Type.Name))