ChangeTypeMode method (Element)

Меняет тип и режим типового объекта.

Применяется к:

Element

Синтаксис:

Visual Basic:

Function ChangeTypeMode(TypeID As Long, ModeId As Long) As Boolean

TypeID - ID нового типа (ObjectType.Id).

ModeId - номер нового режима (нумерация с 1).

Описание:

Метод возвращает True, если тип и режим изменены; изменение сразу вносится в слой. Новый тип должен быть того же графического вида, что и прежний: символ можно перевести только в символьный тип, линию - в линейный.

Если ModeId равен 0, при том же типе режим не меняется, а при смене типа объект получает режим 1.

Метод возвращает False и ничего не меняет, если типа с таким ID в слое нет, у типа нет режима с таким номером, тип другого графического вида или объект - примитив. Сделать типовой объект примитивом метод не позволяет.

Пример:

Пример ставит за краем данных активного слоя символ режима 1 и переключает его на режим 2 того же типа.

Visual Basic:

Sub Element_ChangeTypeMode
'Берем активный слой карты и его габариты
Set L = Zulu.ActiveMapDoc.Layers.Active
Set R = L.GetBoundsRectangle
'Ищем символьный тип, у которого не меньше двух режимов
Set OTs = L.ObjectTypes
Set T = Nothing
For i = 0 To OTs.Count - 1
  Set OT = OTs.GetItemByIndex(i)
  'GraphicType = 1 - символьный тип
  If OT.GraphicType = 1 And OT.Modes.Count >= 2 Then
    Set T = OT
    Exit For
  End If
Next
If T Is Nothing Then
  MsgBox "В слое нет символьного типа с двумя режимами"
Else
  'Ставим символ режима 1 за краем данных слоя
  Key = L.AddSymbol(R.Xmax + (R.Xmax - R.Xmin) / 10, R.Ymin, T.Id, 1)
  Set E = L.Elements.Item(Key)
  'Переключаем символ на режим 2
  If E.ChangeTypeMode(T.Id, 2) Then
    Set E = L.Elements.Item(Key)
    MsgBox "Символ " & Key & ": тип " & E.TypeID & ", режим " & E.ModeId
  Else
    MsgBox "Режим не изменен"
  End If
End If
End Sub

Python:

import zulu

def Macro_Element_ChangeTypeMode():
    # Берем активный слой карты и его габариты
    L = zulu.App.ActiveMapDoc.Layers.Active
    R = L.GetBoundsRectangle()
    # Ищем символьный тип, у которого не меньше двух режимов
    OTs = L.ObjectTypes
    T = None
    for i in range(OTs.Count):
        OT = OTs.GetItemByIndex(i)
        # GraphicType = 1 - символьный тип
        if OT.GraphicType == 1 and OT.Modes.Count >= 2:
            T = OT
            break
    if T is None:
        print("В слое нет символьного типа с двумя режимами")
    else:
        # Ставим символ режима 1 за краем данных слоя
        key = L.AddSymbol(R.Xmax + (R.Xmax - R.Xmin) / 10, R.Ymin, T.Id, 1)
        E = L.Elements.Item(key)
        # Переключаем символ на режим 2
        if E.ChangeTypeMode(T.Id, 2):
            E = L.Elements.Item(key)
            print("Символ", key, ": тип", E.TypeId, ", режим", E.ModeId)
        else:
            print("Режим не изменен")