Mode property (Element)

Возвращает/устанавливает режим типового объекта.

Применяется к:

Element

Синтаксис:

Visual Basic:

Property Mode As ObjectMode

Описание:

При чтении возвращается режим объекта (ObjectMode) - его номер Id и название Name. У примитива свойство возвращает Nothing, у объекта растрового слоя обращение вызывает исключение с кодом 517 (неправильный тип слоя).

Новый режим задается в пределах того же типа номером режима или его названием; изменение сразу вносится в слой. Если у типа нет режима с таким номером или названием, а также у примитива присваивание ничего не меняет и ошибки не вызывает. Объект ObjectMode присвоить нельзя: в Visual Basic возникает ошибка «Type mismatch» (с Set - ошибка 438), в Python - TypeError. Номер режима без обращения к объекту режима дает ModeId, сменить тип вместе с режимом позволяет ChangeTypeMode.

Пример:

Пример ставит за краем данных активного слоя символ режима 1 и переключает его режим сначала номером, затем названием.

Visual Basic:

Sub Element_Mode
'Берем активный слой карты и его габариты
Set L = Zulu.ActiveMapDoc.Layers.Active
Set R = L.GetBoundsRectangle
'Ищем символьный тип, у которого не меньше двух режимов
Set OTs = L.ObjectTypes
Set T = Nothing
For i = 0 To OTs.Count - 1
  Set OT = OTs.GetItemByIndex(i)
  'GraphicType = 1 - символьный тип
  If OT.GraphicType = 1 And OT.Modes.Count >= 2 Then
    Set T = OT
    Exit For
  End If
Next
If T Is Nothing Then
  MsgBox "В слое нет символьного типа с двумя режимами"
Else
  'Ставим символ режима 1 за краем данных слоя
  Key = L.AddSymbol(R.Xmax + (R.Xmax - R.Xmin) / 10, R.Ymin, T.Id, 1)
  'Режим задаем номером
  L.Elements.Item(Key).Mode = 2
  Msg = "Символ " & Key & vbCrLf & "режим 2: " & L.Elements.Item(Key).Mode.Name
  'и названием
  L.Elements.Item(Key).Mode = T.Modes.Item(1).Name
  MsgBox Msg & vbCrLf & "режим по названию: " & L.Elements.Item(Key).ModeId
End If
End Sub

Python:

import zulu

def Macro_Element_Mode():
    # Берем активный слой карты и его габариты
    L = zulu.App.ActiveMapDoc.Layers.Active
    R = L.GetBoundsRectangle()
    # Ищем символьный тип, у которого не меньше двух режимов
    OTs = L.ObjectTypes
    T = None
    for i in range(OTs.Count):
        OT = OTs.GetItemByIndex(i)
        # GraphicType = 1 - символьный тип
        if OT.GraphicType == 1 and OT.Modes.Count >= 2:
            T = OT
            break
    if T is None:
        print("В слое нет символьного типа с двумя режимами")
        return
    # Ставим символ режима 1 за краем данных слоя
    key = L.AddSymbol(R.Xmax + (R.Xmax - R.Xmin) / 10, R.Ymin, T.Id, 1)
    # Режим задаем номером
    L.Elements.Item(key).Mode = 2
    print("Символ", key, ": режим 2 -", L.Elements.Item(key).Mode.Name)
    # и названием
    L.Elements.Item(key).Mode = T.Modes.Item(1).Name
    print("Режим по названию:", L.Elements.Item(key).ModeId)