ModifyByKeyPairs method (Selection)

Изменяет группу по ключам из коллекции пар ElementKeyPairs.

Применяется к:

Selection

Синтаксис:

Visual Basic:

Sub ModifyByKeyPairs(What As eModifySelection, Keys As ElementKeyPairs, nRow As Long)

What - способ изменения: 1 (eSelCreate) - группа создается заново из этих ключей, 2 (eSelAppend) - ключи добавляются, 3 (eSelExclude) - ключи исключаются.

Keys - коллекция пар ключей.

nRow - какой ключ пары брать: 0 - первый (KeyFirst), 1 - второй (KeySecond).

Описание:

Коллекцию пар создать нельзя - ее возвращает метод Layer.IntersectByLayer: первый ключ пары - объект слоя, у которого вызван метод, второй - объект второго слоя. Повторяющиеся ключи учитываются один раз. Ключи не проверяются: группа принимает их, даже если в ее слое таких объектов нет, поэтому для группы слоя, у которого вызывался IntersectByLayer, обычно берут первый ключ. При других значениях What группа не меняется. Коллекция ElementKeys вместо пар вызывает ошибку «Type mismatch» (в Python - TypeError).

Пример:

Пример строит в слое в памяти контур на юго-западную четверть активного слоя и выделяет объекты активного слоя, целиком лежащие в этой области.

Visual Basic:

Sub Selection_ModifyByKeyPairs
Const eFullyInside = 1
Const eSelCreate = 1
'Берем карту, ее активный слой и его габариты
Set M = Zulu.ActiveMapDoc
Set L = M.Layers.Active
Set R = L.GetBoundsRectangle
'Кладем в слой в памяти контур на юго-западную четверть слоя
Idx = M.Layers.AddInMemory("Область")
Set N = M.Layers.Item(Idx)
Set C = CreateObject("ZuluLib.Contour")
C.AddPoint R.Xmin, R.Ymin
C.AddPoint (R.Xmin + R.Xmax) / 2, R.Ymin
C.AddPoint (R.Xmin + R.Xmax) / 2, (R.Ymin + R.Ymax) / 2
C.AddPoint R.Xmin, (R.Ymin + R.Ymax) / 2
N.AddContour C, CreateObject("ZuluLib.ElemStyle"), -1, -1
'Пары ключей: объект активного слоя - контур
Set Pairs = L.IntersectByLayer(N, eFullyInside, False, -1, -1, 0)
'Группа из первых ключей пар
L.Selection.ModifyByKeyPairs eSelCreate, Pairs, 0
MsgBox "Пар: " & Pairs.Count & vbCrLf & "в группе: " & L.Selection.ElementKeys.Count
L.Selection.Clear
M.Layers.Remove Idx
End Sub

Python:

import zulu

eFullyInside = 1
eSelCreate = 1

def Macro_Selection_ModifyByKeyPairs():
    # Берем карту, ее активный слой и его габариты
    M = zulu.App.ActiveMapDoc
    L = M.Layers.Active
    R = L.GetBoundsRectangle()
    # Кладем в слой в памяти контур на юго-западную четверть слоя
    idx = M.Layers.AddInMemory("Область")
    N = M.Layers.Item(idx)
    C = zulu.Contour()
    xm = (R.Xmin + R.Xmax) / 2
    ym = (R.Ymin + R.Ymax) / 2
    for px, py in ((R.Xmin, R.Ymin), (xm, R.Ymin), (xm, ym), (R.Xmin, ym)):
        C.AddPoint(px, py)
    N.AddContour(C, zulu.ElemStyle(), -1, -1)
    # Пары ключей: объект активного слоя - контур
    Pairs = L.IntersectByLayer(N, eFullyInside, False, -1, -1, 0)
    # Группа из первых ключей пар
    L.Selection.ModifyByKeyPairs(eSelCreate, Pairs, 0)
    print("Пар:", Pairs.Count, ", в группе:", L.Selection.ElementKeys.Count)
    L.Selection.Clear()
    M.Layers.Remove(idx)