ConvertToNetwork method (Selection)

Преобразует объекты группы в объекты инженерной сети.

Применяется к:

Selection

Синтаксис:

Visual Basic:

Function ConvertToNetwork(iParams As ConvertToNetworkParams) As Long

iParams - параметры преобразования.

Описание:

Параметры (ConvertToNetworkParams) задают, какие объекты преобразуются и как: например, при включенных ConvertLinePrimitives, InsertIntersectionPoints и SplitLinesByNodes пересекающиеся линии-примитивы делятся в точке пересечения на участки типа и режима, заданных SetTypeModeForLine; в точку пересечения ставится узел (SetTypeModeForJunction), на свободные концы участков - концевые символы (SetTypeModeForDeadlock). У только что созданного объекта параметров все флаги выключены, и с ним метод ничего не меняет. Изменения сразу вносятся в слой.

После вызова группа пуста. Метод возвращает 0, в том числе когда ничего не преобразовано; -1 - если вместо параметров передан Nothing (в Python значение None не принимается: TypeError).

Пример:

Пример добавляет за краем данных активного слоя две пересекающиеся линии-примитива и превращает их в сеть: участки - первого линейного типа слоя, узел и концевые символы - первого символьного.

Visual Basic:

Sub Selection_ConvertToNetwork
'Берем активный слой карты, его группу и габариты
Set L = Zulu.ActiveMapDoc.Layers.Active
Set S = L.Selection
Set R = L.GetBoundsRectangle
'Первый линейный (GraphicType = 2) и первый символьный (GraphicType = 1) типы
TL = -1
TS = -1
Set OTs = L.ObjectTypes
For i = 0 To OTs.Count - 1
  Set OT = OTs.GetItemByIndex(i)
  If OT.GraphicType = 2 And TL = -1 Then TL = OT.Id
  If OT.GraphicType = 1 And TS = -1 Then TS = OT.Id
Next
If TL = -1 Or TS = -1 Then
  MsgBox "В слое нет линейного или символьного типа"
Else
  'Две пересекающиеся линии-примитива за краем данных слоя
  D = (R.Xmax - R.Xmin) / 10
  X = R.Xmax + 2 * D
  Y = R.Ymin + D
  Set A = CreateObject("ZuluLib.PolyLine")
  A.AddPoint X - D, Y
  A.AddPoint X + D, Y
  Set B = CreateObject("ZuluLib.PolyLine")
  B.AddPoint X, Y - D
  B.AddPoint X, Y + D
  S.Clear
  S.AddElem L.AddPolyLine(A, CreateObject("ZuluLib.ElemStyle"), -1, -1)
  S.AddElem L.AddPolyLine(B, CreateObject("ZuluLib.ElemStyle"), -1, -1)
  'Параметры преобразования
  Set Prm = CreateObject("ZuluLib.ConvertToNetworkParams")
  Prm.ConvertLinePrimitives = True
  Prm.InsertIntersectionPoints = True
  Prm.SplitLinesByNodes = True
  Prm.SetTypeModeForLine TL, 1
  Prm.SetTypeModeForJunction TS, 1
  Prm.SetTypeModeForDeadlock TS, 1
  N = L.ElementKeys.Count
  Res = S.ConvertToNetwork(Prm)
  MsgBox "Результат " & Res & vbCrLf & "объектов в слое: " & N & " -> " & L.ElementKeys.Count
End If
End Sub

Python:

import zulu

def Macro_Selection_ConvertToNetwork():
    # Берем активный слой карты, его группу и габариты
    L = zulu.App.ActiveMapDoc.Layers.Active
    S = L.Selection
    R = L.GetBoundsRectangle()
    # Первый линейный (GraphicType = 2) и первый символьный (GraphicType = 1) типы
    OTs = L.ObjectTypes
    types = [OTs.GetItemByIndex(i) for i in range(OTs.Count)]
    tl = next((t.Id for t in types if t.GraphicType == 2), -1)
    ts = next((t.Id for t in types if t.GraphicType == 1), -1)
    if tl == -1 or ts == -1:
        print("В слое нет линейного или символьного типа")
        return
    # Две пересекающиеся линии-примитива за краем данных слоя
    d = (R.Xmax - R.Xmin) / 10
    x = R.Xmax + 2 * d
    y = R.Ymin + d
    S.Clear()
    for (x1, y1), (x2, y2) in (((x - d, y), (x + d, y)), ((x, y - d), (x, y + d))):
        PL = zulu.PolyLine()
        PL.AddPoint(x1, y1)
        PL.AddPoint(x2, y2)
        S.AddElem(L.AddPolyLine(PL, zulu.ElemStyle(), -1, -1))
    # Параметры преобразования
    Prm = zulu.ConvertToNetworkParams()
    Prm.ConvertLinePrimitives = True
    Prm.InsertIntersectionPoints = True
    Prm.SplitLinesByNodes = True
    Prm.SetTypeModeForLine(tl, 1)
    Prm.SetTypeModeForJunction(ts, 1)
    Prm.SetTypeModeForDeadlock(ts, 1)
    n = L.ElementKeys.Count
    res = S.ConvertToNetwork(Prm)
    print("Результат", res, ", объектов в слое:", n, "->", L.ElementKeys.Count)