ElemStyle property (Element)

Возвращает/устанавливает стиль отображения объекта-примитива.

Применяется к:

Element

Синтаксис:

Visual Basic:

Property ElemStyle As ElemStyle

Описание:

Собственный стиль есть только у примитива. Стиль типового объекта задается режимом его типа: у такого объекта свойство возвращает пустой стиль (все значения 0), а запись игнорируется. Стиль, с которым объект выводится на карту, возвращает свойство CurrentElemStyle.

Свойство возвращает копию стиля: чтобы изменить стиль, его получают, меняют и присваивают обратно. В Visual Basic присваивание пишется без Set (E.ElemStyle = St); с Set возникает ошибка 438. Новый стиль сразу вносится в слой.

Пример:

Пример добавляет за краем данных активного слоя синюю линию-примитив и перекрашивает ее в красный цвет.

Visual Basic:

Sub Element_ElemStyle
'Берем карту, ее активный слой и его габариты
Set Doc = Zulu.ActiveMapDoc
Set L = Doc.Layers.Active
Set R = L.GetBoundsRectangle
'Добавляем за краем данных слоя синюю линию-примитив
D = (R.Xmax - R.Xmin) / 10
Set PL = CreateObject("ZuluLib.PolyLine")
PL.AddPoint R.Xmax + D, R.Ymin
PL.AddPoint R.Xmax + 2 * D, R.Ymin
Set St = CreateObject("ZuluLib.ElemStyle")
St.LineColor = RGB(0, 0, 255)
St.LineWidth = 2
Key = L.AddPolyLine(PL, St, -1, -1)
'Берем стиль объекта, меняем цвет и присваиваем обратно без Set
Set E = L.Elements.Item(Key)
Set St = E.ElemStyle
St.LineColor = RGB(255, 0, 0)
E.ElemStyle = St
Doc.Refresh True
MsgBox "Линия " & Key & ": цвет " & L.Elements.Item(Key).ElemStyle.LineColor
End Sub

Python:

import zulu

def Macro_Element_ElemStyle():
    # Берем карту, ее активный слой и его габариты
    doc = zulu.App.ActiveMapDoc
    L = doc.Layers.Active
    R = L.GetBoundsRectangle()
    # Добавляем за краем данных слоя синюю линию-примитив
    d = (R.Xmax - R.Xmin) / 10
    PL = zulu.PolyLine()
    PL.AddPoint(R.Xmax + d, R.Ymin)
    PL.AddPoint(R.Xmax + 2 * d, R.Ymin)
    St = zulu.ElemStyle()
    St.LineColor = 16711680
    St.LineWidth = 2
    key = L.AddPolyLine(PL, St, -1, -1)
    # Берем стиль объекта, меняем цвет и присваиваем обратно
    E = L.Elements.Item(key)
    St = E.ElemStyle
    St.LineColor = 255
    E.ElemStyle = St
    doc.Refresh(True)
    print("Линия", key, ": цвет", L.Elements.Item(key).ElemStyle.LineColor)