CalcLength method (Element)

Возвращает длину линейного объекта в сантиметрах, вычисленную в указанной системе координат указанным способом.

Применяется к:

Element

Синтаксис:

Visual Basic:

Function CalcLength(inCRS As CRS, eMeasure As eMeasureType) As Double

inCRS - система координат, в которой вычисляется длина.

eMeasure - способ вычисления: eMeasureTypeCartesian (0) - на плоскости, eMeasureTypeSpherical (1) - на сфероиде, eMeasureTypeRaw (2) - по координатам слоя без пересчета.

Описание:

Длина возвращается в сантиметрах, как у свойства Length; длина в метрах - значение, деленное на 100. У полигонов, символов и текстов метод возвращает 0.

При eMeasureTypeSpherical координаты объекта пересчитываются из системы координат слоя в inCRS, и длина вычисляется на сфероиде этой системы.

При eMeasureTypeCartesian и географической системе inCRS (широта и долгота) длина также вычисляется на сфероиде. Если inCRS - система в проекции, длина вычисляется на плоскости по координатам слоя: в проекцию inCRS координаты не пересчитываются, и результат совпадает с eMeasureTypeRaw.

При eMeasureTypeRaw длина вычисляется на плоскости по координатам слоя, inCRS не учитывается. У слоя в широте и долготе градусы при этом считаются плоскими координатами, и длина искажена.

Пример:

Пример сообщает длину первого линейного объекта активного слоя на плоскости и на сфероиде в системе координат слоя.

Visual Basic:

Sub Element_CalcLength
Const eMeasureTypeCartesian = 0
Const eMeasureTypeSpherical = 1
'Берем активный слой карты и его систему координат
Set L = Zulu.ActiveMapDoc.Layers.Active
Set C = L.GetCRS
Set K = L.ElementKeys
'Ищем первый линейный объект (графический тип 0 или 4)
Set E = Nothing
For i = 1 To K.Count
  Set El = L.Elements.Item(K.Item(i))
  If El.GraphType = 0 Or El.GraphType = 4 Then
    Set E = El
    Exit For
  End If
Next
If E Is Nothing Then
  MsgBox "В слое нет линий"
Else
  'Длина возвращается в сантиметрах - переводим в метры
  MsgBox "Линия " & E.Key & vbCrLf & _
    "на плоскости: " & E.CalcLength(C, eMeasureTypeCartesian) / 100 & " м" & vbCrLf & _
    "на сфероиде: " & E.CalcLength(C, eMeasureTypeSpherical) / 100 & " м"
End If
End Sub

Python:

import zulu

eMeasureTypeCartesian = 0
eMeasureTypeSpherical = 1

def Macro_Element_CalcLength():
    # Берем активный слой карты и его систему координат
    L = zulu.App.ActiveMapDoc.Layers.Active
    C = L.GetCRS()
    K = L.ElementKeys
    # Ищем первый линейный объект (графический тип 0 или 4)
    E = None
    for i in range(1, K.Count + 1):
        El = L.Elements.Item(K.Item(i))
        if El.GraphType in (0, 4):
            E = El
            break
    if E is None:
        print("В слое нет линий")
    else:
        # Длина возвращается в сантиметрах - переводим в метры
        print("Линия", E.Key, ": на плоскости", E.CalcLength(C, eMeasureTypeCartesian) / 100,
              "м, на сфероиде", E.CalcLength(C, eMeasureTypeSpherical) / 100, "м")