CalcArea method (Element)

Возвращает площадь объекта в гектарах, вычисленную в указанной системе координат указанным способом.

Применяется к:

Element

Синтаксис:

Visual Basic:

Function CalcArea(inCRS As CRS, eMeasure As eMeasureType) As Double

inCRS - система координат, в которой вычисляется площадь.

eMeasure - способ вычисления: eMeasureTypeCartesian (0) - на плоскости, eMeasureTypeSpherical (1) - на сфероиде, eMeasureTypeRaw (2) - по координатам слоя без пересчета.

Описание:

Площадь имеет смысл для площадных объектов; у линий, символов и текстов метод возвращает 0.

При eMeasureTypeCartesian координаты объекта пересчитываются из системы координат слоя в inCRS, и площадь вычисляется на плоскости этой системы: в проекции, искажающей площади (например, Меркатора EPSG:3857), результат искажен так же. Если inCRS - географическая система (широта и долгота), площадь вычисляется на сфероиде.

При eMeasureTypeSpherical площадь вычисляется на сфероиде системы inCRS.

При eMeasureTypeRaw площадь вычисляется на плоскости по координатам слоя, inCRS не учитывается. У слоя в широте и долготе градусы при этом считаются плоскими координатами, и площадь искажена.

Площадь на плоскости в системе координат слоя (eMeasureTypeCartesian с системой слоя Layer.GetCRS) у слоя в проекции совпадает со свойством Area.

Пример:

Пример сообщает площадь первого площадного объекта активного слоя на плоскости и на сфероиде в системе координат слоя.

Visual Basic:

Sub Element_CalcArea
Const eMeasureTypeCartesian = 0
Const eMeasureTypeSpherical = 1
'Берем активный слой карты и его систему координат
Set L = Zulu.ActiveMapDoc.Layers.Active
Set C = L.GetCRS
Set K = L.ElementKeys
'Ищем первый площадной объект (графический тип 1 или 5)
Set E = Nothing
For i = 1 To K.Count
  Set El = L.Elements.Item(K.Item(i))
  If El.GraphType = 1 Or El.GraphType = 5 Then
    Set E = El
    Exit For
  End If
Next
If E Is Nothing Then
  MsgBox "В слое нет площадных объектов"
Else
  MsgBox "Объект " & E.Key & vbCrLf & _
    "на плоскости: " & E.CalcArea(C, eMeasureTypeCartesian) & " га" & vbCrLf & _
    "на сфероиде: " & E.CalcArea(C, eMeasureTypeSpherical) & " га"
End If
End Sub

Python:

import zulu

eMeasureTypeCartesian = 0
eMeasureTypeSpherical = 1

def Macro_Element_CalcArea():
    # Берем активный слой карты и его систему координат
    L = zulu.App.ActiveMapDoc.Layers.Active
    C = L.GetCRS()
    K = L.ElementKeys
    # Ищем первый площадной объект (графический тип 1 или 5)
    E = None
    for i in range(1, K.Count + 1):
        El = L.Elements.Item(K.Item(i))
        if El.GraphType in (1, 5):
            E = El
            break
    if E is None:
        print("В слое нет площадных объектов")
    else:
        print("Объект", E.Key, ": на плоскости", E.CalcArea(C, eMeasureTypeCartesian),
              "га, на сфероиде", E.CalcArea(C, eMeasureTypeSpherical), "га")